blob: a48037fbdfb65af41c513808edb9f9a371bb22bd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
pkgname=glrpt-git
pkgver=r51.d29f449
pkgrel=1
pkgdesc="Interactive GUI application for receiving, decoding and displaying LRPT images from the Russian Meteor-M type of weather satellites"
arch=(i686 x86_64)
license=(GPL3)
url="https://github.com/dvdesolve/glrpt"
depends=('gtk3>=3.22.0' glibc glib2 'soapysdr>=0.8.0' libconfig libjpeg-turbo)
makedepends=(git cmake make)
optdepends=('soapyrtlsdr: RTL-SDR support'
'soapyairspy: Airspy support')
provides=(glrpt)
conflicts=(glrpt)
source=("${pkgname}::git+https://github.com/dvdesolve/glrpt.git")
sha256sums=('SKIP')
pkgver() {
cd "${pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${pkgname}"
mkdir build
cd build
cmake -DCMAKE_INSTALL_PREFIX=/usr ..
make
}
package() {
cd "${pkgname}"
cd build
make DESTDIR="${pkgdir}" install
}
|