PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Joonas Henriksson <joonas.henriksson at gmail com>
# Contributor: Agorgianitis Loukas <agorglouk@gmail.com>

pkgbase=glslviewer-git
pkgname=('glslviewer-git' 'glslviewer-examples-git')
pkgver=3.2.4.r4.gdb3def8
pkgrel=1
pkgdesc="Console-based GLSL Sandbox for 2D/3D shaders"
arch=('i686' 'x86_64')
url="https://github.com/patriciogonzalezvivo/glslViewer"
license=('BSD-3-Clause')
depends=('glu' 'glfw-x11' 'ncurses' 'ffmpeg')
makedepends=('cmake' 'git')
provides=("${pkgbase%-git}")
conflicts=("${pkgbase%-git}")
source=("${pkgbase%-git}::git+https://github.com/patriciogonzalezvivo/glslViewer")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgbase%-git}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "$srcdir/${pkgbase%-git}"
    git submodule init
    git submodule update
}

build() {
    cmake \
        -S "${pkgbase%-git}" \
        -B build \
        -DCMAKE_INSTALL_PREFIX=/usr

    make -C build
}

package_glslviewer-git() {
    make install -C build DESTDIR="$pkgdir"

    install -D -m644 "${pkgbase%-git}/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_glslviewer-examples-git() {
    pkgdesc+=" (shader examples)"
    depends=()
    provides=("${pkgname%-git}")
    conflicts=("${pkgname%-git}")

    install -d -m755 "$pkgdir/usr/share/$pkgname/"
    cp -r "${pkgbase%-git}"/examples/* "$pkgdir/usr/share/$pkgname/"

    install -D -m644 "${pkgbase%-git}/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}