summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 27e9c44ceeb902d5c7e87085eaff0f28b8845007 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Kyle Keen <keenerd@gmail.com>

pkgname=glucose
pkgver=4.1
pkgrel=1
pkgdesc="Parallel SAT solver based on Minisat, with glue clauses."
arch=('i686' 'x86_64')
url="http://www.labri.fr/perso/lsimon/glucose/"
license=('MIT')
depends=('gcc-libs' 'zlib')
# sigh, no versions
source=("http://www.labri.fr/perso/lsimon/downloads/softwares/glucose-syrup-$pkgver.tgz")
md5sums=('7f13be91b3cd71bd02d4f37570fee011')

prepare() {
  cd "$srcdir/glucose-syrup-$pkgver"
  if [[ $CARCH == "armv7h" ]]; then
    sed -i -e 's/ & ~_FPU_EXTENDED//' -e 's/ | _FPU_DOUBLE//' {simp,parallel}/Main.cc
  fi
}

build() {
  export MROOT="$srcdir/$pkgname"
  # r = release, s = static
  cd "$srcdir/glucose-syrup-$pkgver/simp"
  make r
  cd "$srcdir/glucose-syrup-$pkgver/parallel"
  make r
}

package() {
  cd "$srcdir/glucose-syrup-$pkgver"
  install -Dm644 LICENCE "$pkgdir/usr/share/licenses/$pkgname/LICENCE"

  cd "simp"
  install -Dm755 glucose_release "$pkgdir/usr/bin/glucose"
  cd "../parallel"
  install -Dm755 glucose-syrup_release "$pkgdir/usr/bin/glucose-syrup"

}

# vim:set ts=2 sw=2 et: