blob: 4a26caf4dcc6be00b4fa5f89e0002d4aabd979be (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Adrián Pérez de Castro <aperez@igalia.com>
# Maintainer: Alexandre Macabies <web+oss@zopieux.com>
#
pkgname=gn-git
pkgdesc='Meta-build system which generates Ninja build files'
pkgver=r1438.8ce4e49a
pkgrel=2
license=('BSD')
arch=('x86_64' 'i686')
conflicts=('gn-bin')
provides=('gn')
depends=('gcc-libs')
makedepends=('python2' 'ninja' 'clang')
url='https://gn.googlesource.com/gn'
source=("gn::git+${url}")
sha512sums=(SKIP)
pkgver () {
export GIT_DIR="${startdir}/gn"
printf "r%s.%s" "$(git --bare rev-list --count HEAD)" "$(git --bare rev-parse --short HEAD)"
}
build () {
cd gn
python2 build/gen.py
ninja -C out
}
package () {
install -Dm755 gn/out/gn "${pkgdir}/usr/bin/gn"
# Documentation
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" \
gn/tools/gn/docs/*.md
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}/example" \
gn/tools/gn/example/*.*
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}/example/build" \
gn/tools/gn/example/build/*.*
# Vim support
local item
for item in autoload ftplugin ftdetect syntax ; do
install -Dm 644 -t "${pkgdir}/usr/share/vim/vimfiles/${item}" \
"gn/tools/gn/misc/vim/${item}"/*.vim
done
# License
install -m 644 -D gn/LICENSE \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|