PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: xiretza <xiretza+aur@gmail.com>
# Maintainer: Rod Kay <charlie5 on #ada at freenode.net>

pkgname=gnatcoll-gnatinspect
pkgver=2020
pkgrel=1
_repo_name=gnatcoll-db
_upstream_ver=20.2

pkgdesc='GNAT Components Collection - the gnatinspect tool.'
url='https://github.com/AdaCore/gnatcoll-db/'
arch=('i686' 'x86_64')
license=('GPL')

depends=('gnatcoll-core' 'gnatcoll-readline' 'gnatcoll-xref')
makedepends=('gprbuild')

source=("${_repo_name}-${_upstream_ver}.tar.gz::https://github.com/AdaCore/${_repo_name}/archive/${_upstream_ver}.tar.gz")
sha1sums=('cd8e0f62f1fa9bc38f36a9493d20fe46159ce575')

build()
{
    cd "$srcdir/$_repo_name-$_upstream_ver/gnatinspect"

    make setup BUILD=PROD prefix=/usr
    make -j1 GPRBUILD_OPTIONS="-R -cargs $CFLAGS -largs $LDFLAGS -gargs"
}

package()
{
    cd "$srcdir/$_repo_name-$_upstream_ver/gnatinspect"

    # Make one install at a time to avoid GPRinstall reading/writing to
    # the same installed project files at the same time.
    make prefix="$pkgdir/usr" install -j1
}