blob: 5c76942271ef3211b378117afb9c0355c8f1a56d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: xiretza <xiretza+aur@gmail.com>
# Maintainer: Rod Kay <rodakay5 at gmail dot com>
pkgname=gnatcoll-postgres
epoch=1
pkgver=22.0.0
pkgrel=3
_repo_name=gnatcoll-db
pkgdesc='GNAT Components Collection - Postgres database support'
url='https://github.com/AdaCore/gnatcoll-db/'
arch=('i686' 'x86_64')
license=('GPL3' 'custom')
depends=('gnatcoll-sql' 'postgresql')
makedepends=('gprbuild')
source=("https://github.com/AdaCore/gnatcoll-db/archive/refs/tags/v22.0.0.tar.gz")
sha256sums=('8d29e2047adac2de8bc20ae50d12fe6759428197079082d246d7f1cd480d380f')
build()
{
cd "$srcdir/$_repo_name-$pkgver/postgres"
# Rid flags not used by Ada.
CFLAGS="${CFLAGS//-Wformat}"
CFLAGS="${CFLAGS//-Werror=format-security}"
make setup BUILD=PROD prefix=/usr
make -j1 GPRBUILD_OPTIONS="-R -cargs $CFLAGS -largs $LDFLAGS -gargs"
}
package()
{
cd "$srcdir/$_repo_name-$pkgver/postgres"
# Make one install at a time to avoid GPRinstall reading/writing to
# the same installed project files at the same time.
make prefix="$pkgdir/usr" install -j1
# Install the license.
install -D -m644 \
"../COPYING3" \
"$pkgdir/usr/share/licenses/$pkgname/COPYING3"
# Install the custom license.
install -D -m644 \
"../COPYING.RUNTIME" \
"$pkgdir/usr/share/licenses/$pkgname/COPYING.RUNTIME"
}
|