blob: c174bd9df7cfdf76fe44726d26d2ad0f1243325d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Contributor: Andrew Querol <andrew@querol.me>
# Maintainer: Rafael Fontenelle <rafaelff@gnome.org>
pkgname=gnome-browser-connector
pkgver=42.1
pkgrel=3
pkgdesc='Native browser connector for integration with extensions.gnome.org'
arch=(any)
url="https://wiki.gnome.org/Projects/GnomeShellIntegration"
license=(GPL3)
depends=(gnome-shell python-gobject)
makedepends=(meson git)
provides=(chrome-gnome-shell)
replaces=(chrome-gnome-shell gs-chrome-connector)
conflicts=(chrome-gnome-shell gs-chrome-connector)
_commit=1ed2008a39acceaed153b8b3b865081ceba98ab2 # tags/v42.1
source=("git+https://gitlab.gnome.org/GNOME/$pkgname.git#commit=$_commit")
md5sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/^v//;s/-/+/g'
}
prepare() {
cd $pkgname
# Enforce Arch python package's binary, to avoid different python binary in users' PATH
sed -i "s|'python3'|'/usr/bin/python3'|" meson.build
}
build() {
arch-meson $pkgname build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir="$pkgdir"
}
|