PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Maintainer: Sam Burgos < sam dot burgos1089 at gmail dot com >

pkgname=gnome-calendar-linuxmint
_pkgname=gnome-calendar
pkgver=3.30.1
pkgrel=2
pkgdesc="Simple and beautiful calendar application designed to perfectly fit the GNOME desktop. With Linux Mint patches"
url="https://wiki.gnome.org/Apps/Calendar"
arch=('x86_64')
license=('GPL')
depends=('evolution-data-server' 
    'gsettings-desktop-schemas'
    'libdazzle')
makedepends=('appstream-glib' 
    'evolution'
    'git'
    'gtk-doc'
    'meson'
    'python')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
_commit=262dd7e3b03b3eacf3b62c616005119b64e0d35e  # tags/3.30.1^0
source=("git+https://gitlab.gnome.org/GNOME/gnome-calendar.git#commit=$_commit"
        "null-icaltime.diff"
        "add_cinnamon_settings_online_support.patch"
        "set_window_icon_name.patch")
sha256sums=('SKIP'
            'c1aa738a4ff275f725d0aa5406312600503b2b59270448a9e6b30b82a924dc27'
            '2445f754a044dd1ccb8c948b5d5b43248b61ec3570fc76416f74148abc5abf4d'
            '8395252849da14ce048d03a53f17cffad06e345e8b1b47f8fc3681fd7e23345d')

pkgver() {
  cd $_pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $_pkgname
  # Set datetime to NULL in case there is no available date
  patch -Np1 -i ../null-icaltime.diff
  
  # Add support so that gnome-calendar can call this when run within Cinnamon by calling cinnamon-settings online-accounts 
  patch -Np0 -i ../add_cinnamon_settings_online_support.patch
  
  # Fix: Set window icon name
  patch -Np0 -i ../set_window_icon_name.patch 
}

build() {
  arch-meson $_pkgname build \
    --buildtype=debugoptimized \
    -D documentation=true
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}