blob: 639e4c6349a529af9f8a3177484601a396a0a04c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: lectrode (electrodexsnet@gmail.com)
# Contributor: Edgar Vincent <e-v@posteo.net>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
_pkgname=gnome-clocks
pkgname=${_pkgname}-waked
pkgver=44.0
pkgrel=1
pkgdesc="Clocks applications for GNOME (version with waked support)"
url="https://wiki.gnome.org/Apps/Clocks"
arch=(x86_64 aarch64)
license=(GPL)
provides=($_pkgname)
conflicts=($_pkgname)
depends=(
geoclue
geocode-glib-2
gnome-desktop-4
gsound
gtk4
libadwaita
libgweather-4
waked
)
makedepends=(
git
gobject-introspection
meson
vala
yelp-tools
)
groups=(gnome)
_commit=220460fde76ef779436dacb07bc3b0589995e608 # tags/44.0^0
source=("git+https://gitlab.gnome.org/GNOME/gnome-clocks.git#commit=$_commit"
'0001-invoke-waked-when-an-alarm-changes.patch'
'0002-Add-argument-to-start-initial-instance-in-the-backgr.patch'
'0003-add-lock-screen-actions.patch'
'gnome-clocks.desktop')
b2sums=('SKIP'
'f63bd443f2a95b0acfc40989cdaf5b02a857fda14949731e5cdda341e8a26dcd2740bc885bf93087f25224820f1abfdc581919f16f4c47c5591e3348d6917a47'
'940e1bc2d1756bf8c9f7ad26c5b58a6aeb9eb2110f2ab483e6789c32336d54af2679271f5823b5ad8aabf4643cdbb97624440696606f606a64b69379eee31708'
'fcb286f9e4ed9381aa0c6ae46c4f4b27126d1e1236e59dec4f8fd564a5fe9f9c7041764e2ce3dc38af7393a0235aa41753167ad99434ba2ddbaf4e47fe12f8d5'
'1c3891a84f28bf8e8cbf7d0ad8f5d17a6993f91c686986193d5cf71c46368d7d6645de718f09cd4c6b69e4ed118333d02e22b4fb507c21ca55a54135a5c594fc')
pkgver() {
cd $_pkgname
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd $_pkgname
local src
for src in "${source[@]}"; do
src="${src%%::*}"
src="${src##*/}"
[[ $src = *.patch ]] || continue
echo "Applying patch $src..."
patch -Np1 < "../$src"
done
}
build() {
arch-meson $_pkgname build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
install -Dm644 "gnome-clocks.desktop" "${pkgdir}/etc/xdg/autostart/gnome-clocks.desktop"
}
# vim:set sw=2 sts=-1 et:
|