summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: bbd9e597cf0068ab7a10ce06c4bda7fe3207f45a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: Ricardo Liang (rliang) <ricardoliang@gmail.com>

pkgname=gnome-disk-utility-git
pkgver=3.31.2+13+g7f750593
pkgrel=1
pkgdesc="Disk Management Utility for GNOME"
url="https://gitlab.gnome.org/GNOME/gnome-disk-utility"
arch=(x86_64)
license=(GPL)
groups=(gnome)
provides=(gnome-disk-utility)
conflicts=(gnome-disk-utility)
depends=(udisks2 gtk3 libsecret libpwquality libcanberra libdvdread libnotify parted libsystemd)
makedepends=(docbook-xsl appstream-glib git meson)
source=("git+https://gitlab.gnome.org/GNOME/gnome-disk-utility.git")
sha256sums=('SKIP')

pkgver() {
  cd gnome-disk-utility
  git describe --tags | sed 's/-/+/g'
}

build() {
  arch-meson gnome-disk-utility build
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}