blob: 494c9d47cf41eb09fcef83c20b5dc2077193e626 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=gnome-fuzzy-app-search-git
pkgver=4.1.0.r5.g76dee9f
pkgrel=2
pkgdesc="Fuzzy application search results for Gnome Search"
arch=('any')
url="https://gitlab.com/Czarlie/gnome-fuzzy-app-search"
license=('GPL3')
depends=('gnome-shell')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://gitlab.com/Czarlie/gnome-fuzzy-app-search.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$srcdir/${pkgname%-git}"
make build
}
package() {
cd "$srcdir/${pkgname%-git}"
make INSTALL_PATH="$pkgdir/usr/share/gnome-shell/extensions" install
_uuid="${pkgname%-git}@gnome-shell-extensions.Czarlie.gitlab.com"
install -Dm644 schemas/org.gnome.shell.extensions.gnome-fuzzy-search.gschema.xml -t \
"$pkgdir/usr/share/glib-2.0/schemas/"
rm -rf "$pkgdir/usr/share/gnome-shell/extensions/$_uuid/schemas/"
}
|