blob: daf3308d61a0d75c24af0a1eaa4ef14167b1cf41 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=gnome-network-displays-git
pkgver=0.96.0.r1.ge3b63f2
pkgrel=1
pkgdesc="Screencasting for GNOME. Supports the Miracast and Chromecast protocols."
arch=('x86_64')
url="https://gitlab.gnome.org/GNOME/gnome-network-displays"
license=('GPL-3.0-or-later')
depends=(
'avahi'
'dnsmasq'
'gst-plugin-pipewire'
'gst-plugins-bad'
'gst-plugins-good'
'gst-plugins-ugly'
'gst-rtsp-server'
'libadwaita'
'libportal-gtk4'
'libpulse'
'networkmanager'
'protobuf-c'
'xdg-desktop-portal'
)
makedepends=(
'git'
'glib2-devel'
'meson'
)
optdepends=(
'gstreamer-vaapi'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://gitlab.gnome.org/GNOME/gnome-network-displays.git')
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
arch-meson "${pkgname%-git}" build
meson compile -C build
}
check() {
meson test -C build --no-rebuild --print-errorlogs
}
package() {
meson install -C build --no-rebuild --destdir "$pkgdir"
}
|