blob: 102c0826a4edf070835a4728e2ced20fdb5e7cec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=gnome-network-displays-git
pkgver=0.92.1.r2.g3453460
pkgrel=1
pkgdesc="Miracast implementation for GNOME"
arch=('x86_64')
url="https://gitlab.gnome.org/GNOME/gnome-network-displays"
license=('GPL-3.0-or-later')
depends=(
'avahi'
'gst-plugins-bad'
'gst-plugins-good'
'gst-plugins-ugly'
'gst-rtsp-server'
'libadwaita'
'libportal-gtk4'
'libpulse'
'networkmanager'
'protobuf-c'
'python-gobject'
'xdg-desktop-portal'
)
makedepends=('git' 'meson')
optdepends=('dnsmasq' 'gst-plugin-pipewire' 'gstreamer-vaapi')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://gitlab.gnome.org/GNOME/gnome-network-displays.git')
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${pkgname%-git}"
# https://gitlab.gnome.org/GNOME/gnome-network-displays/-/issues/272
sed -i -e "s/args: \['validate'/args: \['--nonet', 'validate'/" \
data/meson.build
}
build() {
arch-meson "${pkgname%-git}" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs || :
}
package() {
meson install -C build --destdir "$pkgdir"
}
|