summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3824ae75924f1f848783ce2e14f106dea5d4b1a1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# Maintainer: twa022 <twa022 at gmail dot com>

pkgbase=gnome-python-desktop
pkgname=('gnome-python-desktop' 'python2-gnomekeyring' 'python2-wnck')
pkgver=2.32.0
pkgrel=19
arch=('i686' 'x86_64')
license=('GPL' 'LGPL')
makedepends=('intltool' 'pkg-config' 'gnome-python' 'libwnck' 'libgnome-keyring')
url="https://www.gnome.org"
source=(https://download.gnome.org/sources/${pkgbase}/${pkgver%.*}/${pkgbase}-${pkgver}.tar.bz2
        01_wnck_enums.patch)
sha256sums=('09dbd580bf3b0ef60f91b090eafe6d08ddcc50a609e2b425a7f8eca46d4e0ee9'
            'e21823dcc1a16174dbf9e48d99c6d3b29fded24ac65dfa55cae9981380a91759')

prepare() {
  cd ${pkgbase}-${pkgver}
  patch -Np1 -i ../01_wnck_enums.patch
}

build() {
  cd ${pkgbase}-${pkgver}
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr --disable-metacity
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package_gnome-python-desktop() {
  depends=('python2-gnomekeyring' 'python2-wnck' 'gnome-python')
  pkgdesc="Python bindings for the GNOME desktop environment"

  cd ${pkgbase}-${pkgver}
  make install-pkgconfigDATA DESTDIR="${pkgdir}"
}

package_python2-gnomekeyring() {
  depends=('pygtk' 'libgnome-keyring')
  pkgdesc="Python bindings for libgnome-keyring"
  conflicts=('python-gnomekeyring<=2.32.0-10')
  replaces=('python-gnomekeyring<=2.32.0-10')

  cd ${pkgbase}-${pkgver}
  make -C gnomekeyring install DESTDIR="${pkgdir}"
}

package_python2-wnck() {
  depends=('pygtk' 'libwnck')
  pkgdesc="Python bindings for libwnck"
  conflicts=('python-wnck<=2.32.0-10')
  replaces=('python-wnck<=2.32.0-10')

  cd ${pkgbase}-${pkgver}
  make -C wnck install DESTDIR="${pkgdir}"
}