blob: 29597ba368be0ccb931e91d4debda0305fd06bba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Christian Schendel <doppelhelix at gmail dot com>
pkgname=gnome-shell-extension-applications-overview-tooltip-git
pkgver=15.r0.g2e86a02
pkgrel=2
pkgdesc="Shows a tooltip over applications icons on applications overview"
arch=(any)
url="https://github.com/RaphaelRochet/applications-overview-tooltip"
install=${pkgname%-git}.install
license=('unknown')
depends=('gnome-shell>=40')
makedepends=('git'
'glib2')
conflicts=("${pkgname%-git}")
provides=(${pkgname%-git})
source=("${pkgname%-git}::git+${url}.git")
sha256sums=('SKIP')
options=('!strip')
pkgver() {
cd "$srcdir/${pkgname%-git}"
git describe --long --tags | sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}
package() {
cd "${srcdir}/${pkgname%-git}"
local uuid=$(grep -Po '(?<="uuid": ")[^"]*' metadata.json)
local schema=$(grep -Po '(?<="settings-schema": ")[^"]*' metadata.json).gschema.xml
local destdir="${pkgdir}/usr/share/gnome-shell/extensions/${uuid}"
install -dm755 "${destdir}"
find . -regextype posix-egrep -regex ".*\.(js|json|xml|css|mo|compiled)$" -exec\
install -Dm 644 {} ${destdir}/{} \;
install -Dm644 "${srcdir}/${pkgname%-git}/schemas/${schema}" \
"${pkgdir}/usr/share/glib-2.0/schemas/${schema}"
# rebuild compiled GSettings schemas if missing
if [[ ! -f "${destdir}/schemas/gschemas.compiled" ]]; then
glib-compile-schemas "${destdir}/schemas"
fi
}
|