blob: ec767020c647f905dcf0827b8d8d65e5163feceb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=gnome-shell-extension-forge-git
_uuid=forge@jmmaranan.com
pkgver=78.r2.g91fb1ea
pkgrel=1
pkgdesc="Tiling and Window Manager for Gnome-Shell"
arch=('any')
url="https://github.com/forge-ext/forge"
license=('GPL-3.0-or-later')
depends=('gnome-shell')
makedepends=('git' 'less')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/forge-ext/forge.git')
sha256sums=('SKIP')
pkgver() {
cd forge
git describe --long --tags | sed 's/^v45-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd forge
make build
}
package() {
cd forge
make INSTALL_PATH="$pkgdir/usr/share/gnome-shell/extensions/${_uuid}" install
mv "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/locale" "$pkgdir/usr/share/"
install -Dm644 schemas/org.gnome.shell.extensions.forge.gschema.xml -t \
"$pkgdir/usr/share/glib-2.0/schemas/"
rm -rf "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/schemas"
}
|