PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=gnome-shell-extension-gpu-profile-selector-git
_uuid=GPU_profile_selector@lorenzo9904.gmail.com
pkgver=gnome.46.r2.g323ff94
pkgrel=1
epoch=1
pkgdesc="Provides a simple way to switch between GPU profiles on NVIDIA Optimus systems"
arch=('any')
url="https://github.com/LorenzoMorelli/GPU_profile_selector"
license=('GPL-3.0-or-later')
depends=('bash' 'envycontrol' 'gnome-shell' 'polkit')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/LorenzoMorelli/GPU_profile_selector.git')
sha256sums=('SKIP')

pkgver() {
  cd GPU_profile_selector
  git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd GPU_profile_selector
  gnome-extensions pack \
     --extra-source=img \
     --extra-source=lib \
     --extra-source=ui \
     --force
}

package() {
  cd GPU_profile_selector
  install -d "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}"
  bsdtar -xvf "${_uuid}.shell-extension.zip" -C \
    "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/" --no-same-owner

  install -Dm644 schemas/org.gnome.shell.extensions.GPU_profile_selector.gschema.xml -t \
    "$pkgdir/usr/share/glib-2.0/schemas"
  rm -rf "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/schemas"
}