blob: 4309094dbaefb8fbab90884d735e455b99b66f99 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Christian Schendel (doppelhelix@gmail.com)
pkgname=gnome-shell-extension-pano-git
pkgver=10.r23.gac43c48
pkgrel=1
pkgdesc="Next-gen Clipboard Manager"
arch=('any')
url="https://github.com/oae/gnome-shell-pano"
install=${pkgname%-git}.install
license=('GPL')
groups=('gnome-shell-extensions')
depends=('gnome-shell>=42'
'libgda6'
'gobject-introspection'
'cogl'
'gsound')
makedepends=('git'
'glib2'
'yarn'
'appstream')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+${url}.git")
options=('!strip')
md5sums=('SKIP')
pkgver() {
cd "${srcdir}/${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${pkgname%-git}"
yarn install
}
build() {
cd "${srcdir}/${pkgname%-git}"
yarn build
}
package() {
cd "${srcdir}/${pkgname%-git}/dist"
local uuid=$(grep -Po '(?<="uuid": ")[^"]*' metadata.json)
local schema=$(grep -Po '(?<="settings-schema": ")[^"]*' metadata.json).gschema.xml
local destdir="${pkgdir}/usr/share/gnome-shell/extensions/${uuid}"
install -dm755 "${destdir}"
find . -regextype posix-egrep -regex ".*\.(js|json|xml|css|mo|compiled|svg|png)$" -exec\
install -Dm 644 {} ${destdir}/{} \;
install -Dm644 "${srcdir}/${pkgname%-git}/dist/schemas/${schema}" \
"${pkgdir}/usr/share/glib-2.0/schemas/${schema}"
# rebuild compiled GSettings schemas if missing
if [[ ! -f "${destdir}/schemas/gschemas.compiled" ]]; then
glib-compile-schemas "${destdir}/schemas"
fi
}
|