PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: surefire@cryptomile.net

pkgname=gnome-shell-extension-quake-mode-git
pkgver=8+1+gd300dfd
pkgrel=1
pkgdesc='Adds support quake-mode for any application'
arch=('any')
url='https://github.com/repsac-by/gnome-shell-extension-quake-mode'
license=('MIT')
depends=('gnome-shell')
makedepends=('git')
conflicts=('gnome-shell-extension-quake-mode')
provides=('gnome-shell-extension-quake-mode')
groups=('gnome-shell-extensions')
source=('git+https://github.com/repsac-by/gnome-shell-extension-quake-mode.git')
sha256sums=('SKIP')

pkgver() {
	cd gnome-shell-extension-quake-mode
	git describe --long --tags | sed 's/^v//;s/-/+/g'
}

build() {
	cd gnome-shell-extension-quake-mode
	gnome-extensions pack --force --extra-source={quakemodeapp,indicator,util}.js quake-mode@repsac-by.github.com
}

package() {
	cd gnome-shell-extension-quake-mode

	local destdir="$pkgdir/usr/share/gnome-shell/extensions/quake-mode@repsac-by.github.com"

	install -d "$destdir"
	bsdtar -C "$destdir" --exclude schemas/ -xf quake-mode@repsac-by.github.com.shell-extension.zip

	install -Dm644 -t "$pkgdir/usr/share/glib-2.0/schemas" quake-mode@repsac-by.github.com/schemas/com.github.repsac-by.quake-mode.gschema.xml

	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}