blob: fd1faf0adfb7323c757fc95645e9d5077908e79b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Patched package maintainer: Saren Arterius <saren@wtako.net>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Flamelab <panosfilip@gmail.com
pkgname=gnome-shell-performance
_pkgname=gnome-shell
pkgver=3.34.0+163+g6a6d66486
pkgrel=1
epoch=1
pkgdesc="Next generation desktop shell"
url="https://wiki.gnome.org/Projects/GnomeShell"
arch=(x86_64)
license=(GPL2)
depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session gnome-settings-daemon
gnome-themes-extra gsettings-desktop-schemas libcanberra-pulse libcroco libgdm libsecret
mutter nm-connection-editor unzip gstreamer libibus gnome-autoar)
makedepends=(gtk-doc gnome-control-center evolution-data-server gobject-introspection git meson
sassc asciidoc)
optdepends=('gnome-control-center: System settings'
'evolution-data-server: Evolution calendar integration')
groups=(gnome)
provides=(gnome-shell gnome-shell=$pkgver)
conflicts=(gnome-shell)
install=gnome-shell-performance.install
_commit=6a6d66486d3326457260f8d1e4b9937d9396c7c6 # master
source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
"git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git"
739.patch)
sha256sums=('SKIP'
'SKIP'
'26c2e9672833e09ff63e314f477897bf67c89fd9769c6b4b73d7300b16afd932')
pkgver() {
cd $_pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $_pkgname
### Adding and fetching remotes providing the selected merge-requests
# git remote add verde https://gitlab.gnome.org/verdre/gnome-shell.git || true
# git fetch verde
### Merge Requests
# Merge Request Prototype
# Title:
# URL:
# Type:
# Status:
# Comment:
# git cherry-pick -n first_commit^..last_commit
#
# Possible Status:
# 1. Needs rebase: Conflicts with master branch.
# 2. Needs review: Mutter maintainers needs to review the new/updated MR and provide feedback.
# 3. Needs changes: MR needs to be adjusted based on maintainers feedback.
# 4. Merged: MR approved and it changes commited to master.
#
# Generally, a MR status oscillate between 2 and 3 and then becomes 4.
#
# Possible Type:
# 1. Improvement: Makes an already existing feature behave better, more efficiently/reliably.
# 2. Feature: Adds a new functionality.
# 3. Fix: Regression/bug fix only available in master (not backported).
# 4. Cleanup: Code styling improvement, function deprecation, rearrangement...
# Empty, because all patches are merged to master as of now
# https://gitlab.gnome.org/GNOME/gnome-shell/issues/1641
git apply -3 ../739.patch
# Un-broke workspaces
git revert ff9bb5399b1d22fceaf00c9fc8e0058f24af96cc --no-commit
git submodule init
git config --local submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
git submodule update
}
build() {
arch-meson $_pkgname build -D gtk_doc=true
ninja -C build
}
package() {
DESTDIR="$pkgdir" meson install -C build
# https://bugs.archlinux.org/task/37412
mkdir "$pkgdir/usr/share/gnome-shell/modes"
}
|