blob: bb2ad05bee288992161431bff72b23bc46a20e72 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Marcin Wieczorek <marcin@marcin.co>
# Contributor: Andrejs Mivreņiks <gim at fastmail dot fm>
# Contributor: Janne Haapsaari <haaja@iki.fi>
# Contributor: maus25 <mirko378@gmail.com>
pkgname=gnome-shell-pomodoro
pkgver=0.12.1
pkgrel=1
pkgdesc='A time management utility for GNOME based on the pomodoro technique'
arch=('i686' 'x86_64')
url='https://github.com/codito/gnome-shell-pomodoro/'
license=('GPL3')
depends=('gnome-desktop' 'libcanberra' 'upower' 'gstreamer' 'gobject-introspection' 'perl-xml-sax-expat' 'telepathy-glib' 'libpeas')
makedepends=('intltool' 'vala' 'gnome-common' 'docbook2x')
conflicts=('gnome-shell-pomodoro-git')
changelog='NEWS'
source=("https://github.com/codito/gnome-pomodoro/archive/$pkgver.tar.gz")
sha256sums=('9857d9a7a2ab62add37d8198a034c78d50c884df18b7368c90689f115e7c8f43')
prepare() {
cd "$srcdir/gnome-pomodoro-$pkgver"
# Fixes some build issues when 'docbook2x' package is installed
# Big thanks to user maus25 for the fix
sed -i "s/docbook2man \$?/docbook2man --sgml \$?/g" man/Makefile.am
./autogen.sh --prefix=/usr --datadir=/usr/share
}
build() {
cd "$srcdir/gnome-pomodoro-$pkgver"
make
}
package() {
cd "$srcdir/gnome-pomodoro-$pkgver"
make DESTDIR="$pkgdir" install
}
|