blob: eb6476fbab9e72475a035be936a3dac8bd406944 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Peter Weber <peter.weber@ttyhoney.com>
# Contributor: Manuel Hüsers <manuel.huesers@uni-ol.de>
# Contributor: Fernando Fernandez <fernando@softwareperonista.com.ar>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-terminal-transparency
_pkgname=gnome-terminal
pkgver=3.26.1
pkgrel=1
pkgdesc="The GNOME Terminal Emulator, with background transparency"
url="https://wiki.gnome.org/Apps/Terminal"
arch=(i686 x86_64)
license=(GPL)
depends=(vte3 gsettings-desktop-schemas dconf)
makedepends=(intltool itstool docbook-xsl libnautilus-extension appdata-tools
gnome-shell gconf vala yelp-tools)
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
options=(!emptydirs)
groups=(gnome)
changelog=$pkgname.changelog
source=(https://download.gnome.org/sources/$_pkgname/${pkgver:0:4}/$_pkgname-$pkgver.tar.xz
gnome-terminal-transparency.patch)
sha256sums=('b9ac564ef77fea0b10502c06bdfca15c4fbdc32fdadaa88d69d7bf0fa1de073a'
'eb0e16e215caac3099d0e7c6573fdf9dbd0f7fe47849dee6157ec12f80074b7c')
prepare() {
cd $_pkgname-$pkgver
patch -Np1 -i ../gnome-terminal-transparency.patch
# possiblity, use autoreconf:
# http://www.gnu.org/software/autoconf/autoconf.html
# https://wiki.debian.org/Autoreconf
# autoreconf -fvi
}
build() {
cd $_pkgname-$pkgver
LDFLAGS+=" -pthread" ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/$_pkgname --disable-static --with-nautilus-extension
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $_pkgname-$pkgver
make check
}
package() {
cd $_pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|