blob: 2c4c6ae965e3876740d3525c7414ae0a9a41af2c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Peter Weber <peter.weber@mailbox.org>
# Contributor: Manuel Hüsers <manuel.huesers@uni-ol.de>
# Contributor: Fernando Fernandez <fernando@softwareperonista.com.ar>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# upstream patches:
# https://src.fedoraproject.org/cgit/rpms/gnome-terminal.git
# https://github.com/debarshiray/gnome-terminal
pkgname=gnome-terminal-transparency
_pkgname=gnome-terminal
pkgver=3.38.3
pkgrel=1
pkgdesc="The GNOME Terminal Emulator with background transparency"
url="https://wiki.gnome.org/Apps/Terminal"
arch=(x86_64)
license=(GPL)
depends=('vte3>=0.62.1' gsettings-desktop-schemas)
makedepends=(itstool docbook-xsl libnautilus-extension appstream-glib
gnome-shell vala yelp-tools)
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
groups=(gnome)
changelog=package.changelog
source=(https://download.gnome.org/sources/$_pkgname/${pkgver:0:4}/$_pkgname-$pkgver.tar.xz
transparency.patch
0001-screen-Manually-handle-env-inheritance.patch
0002-screen-Move-env-sanitization-from-client.patch
0003-screen-Ignore-some-more-environment-variables.patch)
sha256sums=('11a5b0d635f15fdce7508351a510fbf4e92aa533152a50ff0c7845e3102e4764'
'106d36537c621d1b0d4a9a541ee307ace593e005c322fd3622fc64c2f54f70ba'
'c350db9831c3bbe5c28ab5f959076cbeacc1b2bac12ca37623db2bf7d9461ecf'
'4dc0260da875d22830440c3295aef2c73a1625eeeadf94747ac22920d0ddcdca'
'abc5e7b30979a12dc6790d17efc47ec4a112fa6e3e3555ff16c0769b0178c599')
prepare() {
cd $_pkgname-$pkgver
patch -Np1 -i ../transparency.patch
# https://bugs.archlinux.org/task/68318
# https://gitlab.gnome.org/GNOME/gnome-terminal/-/issues/303
patch -Np1 -i ../0001-screen-Manually-handle-env-inheritance.patch
patch -Np1 -i ../0002-screen-Move-env-sanitization-from-client.patch
patch -Np1 -i ../0003-screen-Ignore-some-more-environment-variables.patch
# autogen.sh not in tarball
autoreconf -fiv
}
build() {
cd $_pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib --disable-static --with-nautilus-extension
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $_pkgname-$pkgver
make check
}
package() {
cd $_pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|