blob: a2841d6fd01fe068195e3a59a72bea8e7d1e81ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Peter Weber <peter.weber@ttyhoney.com>
# Contributor: Manuel Hüsers <manuel.huesers@uni-ol.de>
# Contributor: Fernando Fernandez <fernando@softwareperonista.com.ar>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-terminal-transparency
_pkgname=gnome-terminal
pkgver=3.22.0+4+g87e36d3
pkgrel=1
pkgdesc="The GNOME Terminal Emulator, with background transparency"
url="https://wiki.gnome.org/Apps/Terminal"
arch=(i686 x86_64)
license=(GPL)
depends=(vte3 gsettings-desktop-schemas dconf)
makedepends=(intltool itstool docbook-xsl libnautilus-extension appdata-tools
gnome-shell gconf vala yelp-tools git)
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
options=(!emptydirs)
groups=(gnome)
changelog=$pkgname.changelog
_commit=87e36d320ff9819948a2c8398c71f8b57075063a # gnome-3-22
source=("git://git.gnome.org/gnome-terminal#commit=$_commit"
gnome-terminal-transparency.patch)
sha256sums=('SKIP' # current official package from Archlinux does this
'5d893e75f973bf2d639cc56e9dad685a76495eb8c55c88a1c2ad4338799a0e51')
pkgver() {
cd $_pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $_pkgname
patch -Np1 -i ../gnome-terminal-transparency.patch
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $_pkgname
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/$_pkgname --disable-static --with-nautilus-extension
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $_pkgname
make check
}
package() {
cd $_pkgname
make DESTDIR="$pkgdir" install
}
|