blob: 5b3854ba6d116abb1fb9038c702f685ae2eaa2db (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: vinszent <vinszent@vinszent.com>
_gitname=gnome-twitch
pkgname=gnome-twitch-player-backend-gstreamer-cairo
pkgver=0.4.0
pkgrel=2
pkgdesc="GStreamer Cairo (software rendering) player backend for GNOME Twitch"
arch=('i686' 'x86_64')
url="https://github.com/vinszent/gnome-twitch"
license=('GPL3')
makedepends=('git' 'meson')
depends=('gnome-twitch' 'gtk3' 'gstreamer' 'gst-libav' 'gst-plugins-base' 'gst-plugins-good' 'gst-plugins-bad' 'libpeas' 'gobject-introspection')
source=("https://github.com/Ippytraxx/gnome-twitch/archive/v${pkgver}.tar.gz"
"0001-Fix-typo-in-Meson-build-options.patch")
md5sums=('42abec672144865828a9eb4764037a3a'
'9efc76e74fbfd6ca20a2b474b0980002')
conflicts=('gnome-twitch-player-backend-gstreamer-cairo-git')
prepare()
{
cd "${_gitname}-${pkgver}"
patch -p1 -i ../0001-Fix-typo-in-Meson-build-options.patch
}
build()
{
cd "${_gitname}-${pkgver}"
rm -rf build
mkdir build
cd build
meson --prefix /usr --libdir lib --buildtype release \
-Dbuild-executable=false \
-Dbuild-player-backends=gstreamer-cairo ..
ninja
}
package()
{
cd "${_gitname}-${pkgver}/build"
DESTDIR="$pkgdir" ninja install
}
|