blob: 747a27135f5851863d58fdc68c6214380f90bf83 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Co Maintainer: harshadgavali <harshadgavali5022 at gmail dot com>
pkgname=gnome-x11-gesture-daemon
_name=gesture_improvements_gesture_daemon
pkgver=0.2.1
pkgrel=1
pkgdesc="GNOME gesture improvements daemon"
arch=('x86_64')
url="https://github.com/harshadgavali/gnome-x11-gesture-daemon"
license=('MIT')
depends=('libinput')
makedepends=('cargo' 'git' 'setconf')
install="$pkgname.install"
_commit=38529d479ef086d7cd9005529061e96114bca4a9
source=("git+https://github.com/harshadgavali/gnome-x11-gesture-daemon.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$pkgname"
git describe --tags | sed 's/^v//;s/-/+/g'
}
prepare() {
cd "$srcdir/$pkgname"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
setconf "$_name.service" ExecStart "/usr/bin/$_name"
}
build() {
cd "$srcdir/$pkgname"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
package() {
cd "$srcdir/$pkgname"
install -Dm755 "target/release/$_name" -t "$pkgdir/usr/bin/"
install -Dm644 "$_name.service" -t "$pkgdir/usr/lib/systemd/user"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|