blob: e5e8ab779251683b1a7e213cf6bfea3be375ba52 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Stephan Springer <buzo+arch@Lini.de>
# Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux@free.fr>
# Contributor: korjjj <korjjj+aur[at]gmail[dot]com>
pkgname=gns3-gui
pkgver=2.2.27
pkgrel=1
pkgdesc='GNS3 network simulator. Graphical user interface package.'
arch=('any')
url='https://github.com/GNS3/gns3-gui'
license=('GPL3')
groups=('gns3')
depends=(
'desktop-file-utils'
'python-distro'
'python-jsonschema'
'python-psutil'
'python-pyqt5'
'python-sentry_sdk'
'python-setuptools'
'python-sip'
'qt5-svg'
'qt5-websockets'
)
optdepends=(
'gns3-server: GNS3 backend. Manages emulators such as Dynamips, VirtualBox or Qemu/KVM'
'xterm: Default terminal emulator for CLI management of virtual instances'
'wireshark-qt: Live packet capture')
source=("$pkgname-$pkgver.tar.gz::https://github.com/GNS3/$pkgname/archive/v$pkgver.tar.gz"
'gns3.desktop')
sha256sums=('c5afadd2932703c38fb6d479be6966af65787ddc6abcb3f9b7c0b3f5722e0fd5'
'51e6db5b47e6af3d008d85e8c597755369fafb75ddb2af9e79a441f943f4c166')
prepare() {
cd "$pkgname-$pkgver"
# Arch usually has the latest versions. Patch requirements to allow them.
sed -i \
-e 's|^psutil==5\.8\.0$|psutil>=5.8.0|' \
-e 's|^sentry-sdk==1\.3\.1$|sentry-sdk>=1.3.1|' \
-e 's|^distro==1\.6\.0$|distro>=1.6.0|' \
requirements.txt
}
build() {
cd "$pkgname-$pkgver"
python setup.py build
}
package() {
cd "$pkgname-$pkgver"
python setup.py install --root="$pkgdir" --optimize=1
install -Dm644 "$srcdir"/gns3.desktop "$pkgdir"/usr/share/applications/gns3.desktop
install -Dm644 resources/images/gns3_icon_256x256.png "$pkgdir"/usr/share/pixmaps/gns3.png
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|