blob: 6ce19447df87fbf5089571327bf966a2405210cf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: not_anonymous <nmlibertarian@gmail.com>
# Co-Maintainer: Jeb Rosen <jeb@jebrosen.com>
# Based on gnucash-latest <- aur package
# ^^^^^ Maintainer: Neng Xu <neng2.xu2@gmail.com>
# ^^^^^ Contributor: quizzmaster
# Updated w/ help of gnucash-gtk3-git <- aur package
# ^^^^^ Maintainer: Jeb Rosen <jeb@jebrosen.com>
# ^^^^^ Contributor: Juergen Hoetzel <juergen@archlinux.org>
# ^^^^^ Contributor: Mark Schneider <queueRAM@gmail.com>
pkgname=gnucash-git
_pkgname=gnucash
__pkgname=Gnucash
pkgver=2.7.4
#.r4.gfb7426b60
pkgrel=1
pkgdesc="A personal and small-business financial-accounting application - GIT version"
arch=('i686' 'x86_64')
url="http://www.gnucash.org"
license=("GPL")
depends=('aqbanking' 'libdbi-drivers' 'libgnomecanvas' 'boost-libs' \
'slib' 'webkit2gtk')
optdepends=('evince: for print preview'
'perl-date-manip: for stock information lookups'
'perl-finance-quote: for stock information lookups')
makedepends=('git' 'intltool' 'boost' 'swig' 'gtest' 'gmock' 'cmake' 'sqlite3' 'libmariadbclient' 'postgresql-libs')
options=('!emptydirs')
conflicts=('gnucash' 'gnucash-devel' 'gnucash-latest' 'gnucash-gtk3-git' 'gnucash-python' 'gnucash-xbt')
provides=('gnucash')
install=gnucash.install
source=("$pkgname::git+https://github.com/${__pkgname}/${_pkgname}.git")
pkgver() {
cd "$srcdir/$pkgname"
( set -o pipefail
git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build() {
cd "$srcdir/$pkgname"
mkdir -p build
cd build
cmake .. \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=/usr/lib \
-DCMAKE_INSTALL_LIBEXECDIR=/usr/lib \
-DWITH_OFX=ON \
-DWITH_AQBANKING=ON \
-DCMAKE_BUILD_TYPE=RelWithDebInfo
make VERBOSE=1
}
#check() {
# cd "$srcdir/$pkgname"
#
## make check
# make -i check # Needed unless locale -a includes en_US, en_GB, fr_FR (& other(s)?).
#}
package() {
cd "$srcdir/$pkgname/build"
make DESTDIR="${pkgdir}" install
# TODO: tell cmake not to make this file in the first place
rm -f "${pkgdir}"/usr/share/glib-2.0/schemas/*.compiled
# Delete the gnucash-valgrind executable because the source files
# are not included with the package and the executable is hardlinked
# to the location that it was built at.
rm -f "${pkgdir}"/usr/bin/gnucash-valgrind
}
md5sums=('SKIP')
sha256sums=('SKIP')
|