blob: 02e71cf93d859380411058affaf2f3d23383df9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# $Id$
# Maintainer: Ido Rosen <ido@kernel.org>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>
#
# NOTE: To request changes to this package, please submit a pull request
# to the GitHub repository at https://github.com/ido/packages-archlinux
# Otherwise, open a GitHub issue. Thank you! -Ido
#
pkgname=gnupg-largekeys
pkgver=2.0.24
pkgrel=2
pkgdesc='Complete and free implementation of the OpenPGP standard'
url='http://www.gnupg.org/'
license=('GPL')
arch=('i686' 'x86_64')
optdepends=('curl: gpg2keys_curl'
'libldap: gpg2keys_ldap'
'libusb-compat: scdaemon')
makedepends=('curl' 'libldap' 'libusb-compat')
depends=('bzip2' 'libksba' 'libgcrypt' 'pth' 'libassuan' 'readline' 'pinentry' 'dirmngr')
source=("ftp://ftp.gnupg.org/gcrypt/${pkgname%%-largekeys}/${pkgname%%-largekeys}-${pkgver}.tar.bz2"{,.sig}
'protect-tool-env.patch'{,.sig}
'filter.patch'{,.sig}
'gnupg2-large-keys.patch'{,.sig}
'install'{,.sig}
'PKGBUILD.sig')
sha1sums=('010e027d5f622778cadc4c124013fe515ed705cf' 'SKIP'
'2ec97ba55ae47ff0d63bc813b8c64cb79cef11db' 'SKIP'
'e99aa2b725342aee188d706b42d392efb2389cf4' 'SKIP'
'a77b9616d238fbdd5488e7024e5e1f36ce8ed586' 'SKIP'
'ff80fc79329cfa631c19ae1ea6fc4a390ab851f7' 'SKIP'
'SKIP')
install=install
conflicts=('gnupg2' 'gnupg')
provides=("gnupg2=${pkgver}" "gnupg=${pkgver}")
replaces=('gnupg2' 'gnupg')
prepare() {
cd "${srcdir}/${pkgname%%-largekeys}-${pkgver}"
patch -p1 -i ../protect-tool-env.patch # FS#31900
patch -p1 -i ../filter.patch
patch -p1 -i ../gnupg2-large-keys.patch
}
build() {
cd "${srcdir}/${pkgname%%-largekeys}-${pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--libexecdir=/usr/lib/gnupg \
--enable-maintainer-mode \
--enable-standard-socket \
--enable-symcryptrun \
--enable-gpgtar \
make
}
check() {
cd "${srcdir}/${pkgname%%-largekeys}-${pkgver}"
make check
}
package() {
cd "${srcdir}/${pkgname%%-largekeys}-${pkgver}"
make DESTDIR="${pkgdir}" install
ln -s gpg2 "${pkgdir}"/usr/bin/gpg
ln -s gpgv2 "${pkgdir}"/usr/bin/gpgv
ln -s gpg2.1.gz "${pkgdir}"/usr/share/man/man1/gpg.1.gz
rm "${pkgdir}/usr/share/gnupg/com-certs.pem" # FS#33059
}
|