blob: 64d8b87cb9f267c04d0ff107d19c250c7e37f29d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=gnurl-git
pkgver=7.60.0.r1.g5cf58a8cf
pkgrel=1
pkgdesc="gnurl is a fork of curl"
arch=('i686' 'x86_64')
url="https://gnunet.org/gnurl"
license=('MIT')
depends=('glibc' 'gnutls' 'krb5' 'libnghttp2' 'libpsl')
makedepends=('git')
provides=('gnurl')
conflicts=('gnurl')
options=('staticlibs')
source=("git+https://git.taler.net/gnurl.git")
sha256sums=('SKIP')
pkgver() {
cd "gnurl"
git describe --long --tags | sed 's/^gnurl-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "gnurl"
./buildconf
./configure \
--prefix="/usr" \
--mandir="/usr/share/man" \
--with-gssapi \
--with-gnutls \
--with-ca-bundle="/etc/ssl/certs/ca-certificates.crt" \
--with-nghttp2
make
}
check() {
cd "gnurl"
#make check
}
package() {
cd "gnurl"
make DESTDIR="$pkgdir" install
install -Dm644 "COPYING" "$pkgdir/usr/share/licenses/gnurl/COPYING"
}
|