PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Tony Lambiris <tony@libpcap.net>

pkgname=gobuster-git
pkgver=3.5.0.r0.gc3fed5e
pkgrel=1
pkgdesc="A directory/file & DNS busting tool."
arch=('x86_64')
url="https://github.com/OJ/gobuster"
license=('Apache')
makedepends=('go>=1.10' 'git')
conflicts=('gobuster')
provides=('gobuster')
source=("${pkgname}::git+${url}")
sha256sums=('SKIP')

pkgver() {
    cd "${srcdir}/${pkgname}"

    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//g'
}

prepare() {
    cd "${srcdir}/${pkgname}"

    install -m755 -d "${srcdir}/go/src/github.com/OJ/"
    ln -sf "${srcdir}/${pkgname}" "${srcdir}/go/src/github.com/OJ/gobuster"
}

build() {
    cd "${srcdir}/go/src/github.com/OJ/gobuster"

    mkdir -p build

    export GOPATH="${srcdir}/go"
    go build \
        -trimpath -modcacherw -ldflags "-s -w" \
        -o build/gobuster .
}

check() {
    cd "${srcdir}/go/src/github.com/OJ/gobuster"

    export GOPATH="${srcdir}/go"
    make test
}

package() {
    cd "${srcdir}/go/src/github.com/OJ/gobuster"

    install -Dm755 build/gobuster "${pkgdir}/usr/bin/gobuster"
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}