1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Maintainer: HurricanePootis <hurricanepootis@protonmail.com>
# Contributor: seth <getchoo at tuta dot io>
# Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor: loqs
# Contributor: Jorge Araya Navarro <jorgejavieran@yahoo.com.mx>
# Contributor: Cristian Porras <porrascristian@gmail.com>
# Contributor: Matthew Bentley <matthew@mtbentley.us>
_pkgname=godot
pkgname=godot3
pkgver=3.5.3
pkgrel=6
pkgdesc='Advanced cross-platform 2D and 3D game engine (3.x Branch)'
url='https://godotengine.org'
license=(MIT)
arch=(x86_64)
makedepends=(gcc scons yasm alsa-lib pulse-native-provider)
depends=(embree3 freetype2 libglvnd libtheora libvorbis libvpx libwebp libwslay
libsquish libxcursor libxi libxinerama libxrandr opusfile miniupnpc)
optdepends=(pipewire-alsa pipewire-pulse)
source=("$_pkgname-$pkgver.tar.gz::https://github.com/godotengine/godot/archive/$pkgver-stable.tar.gz"
"https://gitlab.archlinux.org/archlinux/packaging/packages/godot/-/raw/main/miniupnpc-2.2.8.patch"
"godot3.patch")
b2sums=('07ee037803e103f863e56a00c6106d00834870881ec75ecc43f947ea3d6e04a560763aa183661fa6437c4c8307f9231b250f2d51462057add1720d71d2ada827'
'ad308b3ed7fdd0ee305151c584e1a37c753dc5856b0afc631342c03f386a45723d2193d5a6937598a1b883d847dc3ac9c5f7db3d66ec3f9283f636e301235e50'
'5ed41b79e0121e66614cce997d8c05b3efafefb45d93a426fe4f63bc9917a8dad8519d3f11021a62d6b3a8f7210f2cc86d03361a51dcf79007b0eb71289c1370')
prepare() {
# Disable the check that adds -no-pie to LINKFLAGS, for gcc != 6
sed -i 's,0] >,0] =,g' $_pkgname-$pkgver-stable/platform/x11/detect.py
# Make godot build a binary compatible with Godot 4
cd "$srcdir/$_pkgname-$pkgver-stable"
patch -p1 < "$srcdir/godot3.patch"
patch -p1 < "$srcdir/miniupnpc-2.2.8.patch"
}
build() {
# Not unbundled (yet):
# bullet (FS#72924, https://github.com/godotengine/godot/issues/55599)
# certs (FS#72762)
# enet (contains no upstreamed IPv6 support)
# recast, xatlas
# AUR: libwebm
local to_unbundle="embree freetype libogg libpng libsquish libtheora libvorbis libvpx libwebp opus pcre2 wslay zlib zstd miniupnpc"
local system_libs=""
for _lib in $to_unbundle; do
system_libs+="builtin_"$_lib"=no "
rm -rf $srcdir/$_pkgname-$pkgver-stable/thirdparty/$_lib
done
cd $srcdir/$_pkgname-$pkgver-stable
export BUILD_NAME=arch_linux
scons -j$(nproc) \
bits=64 \
colored=yes \
platform=x11 \
pulseaudio=yes \
system_certs_path=/etc/ssl/certs/ca-certificates.crt \
target=release_debug \
tools=yes \
use_llvm=no \
CFLAGS="$CFLAGS -fPIC -Wl,-z,relro,-z,now -w" \
CXXFLAGS="$CXXFLAGS -fPIC -Wl,-z,relro,-z,now -w" \
LINKFLAGS="$LDFLAGS" \
$system_libs
}
package() {
# make godot3 compatible with godot
cd "$srcdir/$_pkgname-$pkgver-stable/misc/dist/linux/"
sed -i 's/Godot Engine/Godot Engine 3 LTS/g' org.godotengine.Godot.desktop
cd $srcdir/$_pkgname-$pkgver-stable
install -Dm644 misc/dist/linux/org.godotengine.Godot.desktop \
"$pkgdir/usr/share/applications/org.godotengine.Godot3.desktop"
install -Dm644 icon.svg "$pkgdir/usr/share/pixmaps/$pkgname.svg"
install -Dm755 bin/godot.x11.opt.tools.64 "$pkgdir/usr/bin/$pkgname"
install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 misc/dist/linux/godot.6 "$pkgdir/usr/share/man/man6/$pkgname.6"
install -Dm644 misc/dist/linux/org.godotengine.Godot.xml \
"$pkgdir/usr/share/mime/packages/org.godotengine.Godot3.xml"
}
|