blob: b93b591a24abf4c06001e054289d00e9a0e3a151 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Ainola
pkgname=gog-terraria
pkgver=2.13.0.16
pkgrel=2
pkgdesc="The very world is at your fingertips as you fight for survival, fortune, and glory."
url="http://terraria.org/"
license=('custom')
arch=('i686' 'x86_64')
depends=('sdl2')
# If Firejail is installed, this application will be sandboxed automatically.
optdepends=('firejail: Automatically sandbox this application from your OS')
source=("gog://${pkgname//-/_}_${pkgver}.sh"
"${pkgname}.desktop"
"$pkgname")
sha256sums=('0ef29ce47158ecc55e680a7dc99458b599eabd45c99200437b19f2647b254c37'
'815bf359c2828cdefee1e33a978a84a2ebb538450197a5792b62e382ae3e3093'
'939f39e8b8cbb30ae95648d299008df030b6c6e8e583893da1916e024b493e5b')
# You need to download the gog.com installer file manually or with lgogdownloader.
DLAGENTS+=("gog::/usr/bin/echo %u - This is is not a real URL, you need to download the GOG file manually to \"$PWD\" or setup a gog:// DLAGENT. Read this PKGBUILD for more information.")
# Prevent compressing final package
PKGEXT='.pkg.tar'
prepare(){
# Unzip will produce an error code because it is unable to unzip the Installer.
# Therefore, a conditional into a no-op command will keep the PKGBUILD from failing
# Of course, if you have any real problems unzipping the PKGBUILD will not abort.
unzip -d "${srcdir}/terraria" "${pkgname//-/_}_${pkgver}.sh" || :
}
package(){
cd "${srcdir}/terraria/data/noarch"
# Install game
install -d "${pkgdir}/opt/${pkgname}/"
install -d "${pkgdir}/opt/${pkgname}/support"
install -d "${pkgdir}/usr/bin/"
cp -r "game/" "${pkgdir}/opt/${pkgname}/"
install -Dm755 "start.sh" \
"${pkgdir}/opt/${pkgname}/"
install -Dm755 support/*.{sh,shlib} -t \
"${pkgdir}/opt/${pkgname}/support"
# Desktop integration
install -Dm644 "support/icon.png" \
"${pkgdir}/usr/share/pixmaps/${pkgname}.png"
install -Dm644 "docs/End User License Agreement.txt" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "${srcdir}/${pkgname}.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
install "$srcdir/$pkgname" "$pkgdir/usr/bin/$pkgname"
}
|