blob: 0799bbe208be494317c0abd57c699998f4dd3c27 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=gog-we-are-not-alone
pkgver=1.9.3.1
pkgrel=1
pkgdesc='First-person horror combined with third-person adventure. GOG version.'
_shortname="${pkgname#gog-}"
arch=('x86_64')
url="https://www.gog.com/en/game/${_shortname//-/_}"
license=('LicenseRef-eula')
depends=(
'bash'
'cairo'
'gcc-libs'
'gdk-pixbuf2'
'glib2'
'glibc'
'gtk2'
'pango'
'zlib'
)
makedepends=('lgogdownloader')
options=('!debug' '!strip')
source=(
"${_shortname}_${pkgver//./_}.sh::gogdownloader://${_shortname//-/_}/en3installer0"
"${pkgname}.desktop"
"${_shortname}.bash"
)
sha512sums=(
'cbf06c9c61ff117c3af6ddd626ce3e91fd3f66365c445f53458536575be7c746a246cf10a0a6e071f32ee5fab7e575428cc390c82ac0059932a7092894cad6b0'
'4843f97a977edf7719dc89e6ad17aa584f0c978ad68b6d166b3559409bcbd7e98f67557c2e991071f2297d36a2424a1243b2d8689899f3018b0a1aa2f51695e9'
'e8784cebf629356d92b307a313899c75d1c9d0b3546bf91e18c7bf9a60a77662af49c2954174b46cdcb937f572529793822ab7a45ba26001ffa1cbdb3405070e'
)
DLAGENTS+=('gogdownloader::/usr/bin/lgogdownloader --download-file=%u -o %o')
PKGEXT=.pkg.tar
prepare() {
# Assert that pkgver matches the downloaded version
diff -u \
--label 'Expected version' <(printf "%s Linux\n" "${pkgver}") \
--label 'Actual version' <(awk 'NR==2' data/noarch/gameinfo)
# Remove unneeded 32-bit executable
# Fixes false alarm in rebuild-detector
rm -rfv "${srcdir}/data/noarch/support/yad/32"
}
package() {
echo >&2 'Packaging license'
install -D -m 644 -T \
"${srcdir}/data/noarch/docs/End User License Agreement.txt" \
"${pkgdir}/usr/share/licenses/${pkgname}/End User License Agreement.txt"
echo >&2 'Packaging game icon'
install -D -m 644 -T \
"${srcdir}/data/noarch/support/icon.png" \
"${pkgdir}/usr/share/pixmaps/${pkgname}.png"
echo >&2 'Packaging game data'
mkdir -p "${pkgdir}/opt/${_shortname}"
cp -R --preserve=mode \
"${srcdir}"/data/noarch/* \
"${pkgdir}/opt/${_shortname}"
echo >&2 'Packaging launcher'
install -D -m 755 -T \
"${srcdir}/${_shortname}.bash" \
"${pkgdir}/usr/bin/${_shortname}"
echo >&2 'Packaging desktop file'
install -D -m 755 -T \
"${srcdir}/${pkgname}.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
}
|