blob: b519d038cc7d3652fb55b82b9d24b505866527b2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
pkgbase=goland
pkgname=(goland goland-jre)
pkgver=2019.3.3
pkgrel=1
arch=('x86_64' 'i686')
url='https://www.jetbrains.com/go/'
license=('commercial')
depends=('glib2')
options=('!strip')
source=("https://download.jetbrains.com/go/${pkgbase}-${pkgver}.tar.gz"
jetbrains-goland.desktop
LICENSE)
sha512sums=('e2a8120cbec9d49cbf8b565dfbf12e0da943a9f0b76bff68ffd98c504612698f5bac9c66cf1de91081ed79ea86892630ac7f270312d1c6da0cb2b8683d085a00'
'930a0f1269b7f49f7a08fd5fbfff178628114dee01f4e4e8426c643d7c442b77f178b5188325caf0ace5503c5f873a419cd3f7128b63d7c3c9baf8065b0065aa'
'e2aaaa75571f368f85bcc4baef27cc502781ce382bf04737763b07244716918fc2f0eb0b78b02631e242c9a5c246b27d720bb28556fc64bbde213403b7bf57f6')
package_goland() {
pkgdesc='Capable and Ergonomic Go IDE'
optdepends=('goland-jre: JetBrains custom Java Runtime (Recommended)'
'java-runtime: JRE - Required if goland-jre is not installed')
conflicts=('gogland')
replaces=('gogland')
install -dm755 "${pkgdir}"/opt/
install -dm755 "${pkgdir}"/usr/bin/
install -dm755 "${pkgdir}"/usr/share/applications/
install -dm755 "${pkgdir}"/usr/share/pixmaps/
cp -a "${srcdir}"/GoLand-${pkgver}/ "${pkgdir}"/opt/${pkgbase}
rm -rf "${pkgdir}"/opt/${pkgbase}/jbr
ln -s /opt/${pkgbase}/bin/${pkgbase}.sh "${pkgdir}"/usr/bin/${pkgbase}
install -m644 "${srcdir}"/jetbrains-${pkgbase}.desktop "${pkgdir}"/usr/share/applications/
install -m644 "${pkgdir}"/opt/${pkgbase}/bin/${pkgbase}.png "${pkgdir}"/usr/share/pixmaps/${pkgbase}.png
install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.txt
}
package_goland-jre() {
pkgdesc='JBR (JetBrains Runtime) for Goland - a patched JRE'
url='https://confluence.jetbrains.com/display/JBR/JetBrains+Runtime'
conflicts=('gogland-jre')
replaces=('gogland-jre')
install -dm755 "${pkgdir}"/opt/${pkgbase}
cp -a "${srcdir}"/GoLand-${pkgver}/jbr "${pkgdir}"/opt/${pkgbase}
}
|