blob: 07b03fb2c073c5683b498954a9d24ef9beafd32b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: ml <ml@visu.li>
pkgname=golang-mockery
_pkgname=${pkgname##golang-}
pkgver=2.2.2
pkgrel=1
pkgdesc='A mock code autogenerator for golang'
arch=('x86_64')
url='https://github.com/vektra/mockery'
license=('BSD')
depends=('glibc')
makedepends=('go')
source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('b9f3311706ec9b5936b1a9d9b3014c3183132b1fd347500f8eb5deab0ab5582d')
prepare() {
cd "${_pkgname}-${pkgver}"
go mod download
}
build() {
cd "${_pkgname}-${pkgver}"
export CGO_ENABLED=1
export CGO_LDFLAGS="$LDFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export GOFLAGS='-buildmode=pie -modcacherw -mod=readonly -trimpath'
go build -o bin/${_pkgname} -ldflags "-linkmode=external -X github.com/vektra/mockery/mockery.SemVer=${pkgver}"
}
check() {
cd "${_pkgname}-${pkgver}"
go test ./...
}
package() {
cd "${_pkgname}-${pkgver}"
install -Dm755 bin/${_pkgname} -t "${pkgdir}/usr/bin"
install -Dm755 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|