blob: dab556f867a8b33290814c1ecf8d55a9a4a0153e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: envolution
# Contributor: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Morteza NourelahiAlamdari <m@0t1.me>
# shellcheck shell=bash disable=SC2034,SC2154
pkgname=google-crc32c
pkgver=1.1.2
pkgrel=5
pkgdesc="CRC32C implementation with support for CPU-specific acceleration instructions"
arch=(x86_64)
url="https://github.com/google/crc32c"
license=(BSD-3-Clause)
depends=(
gcc-libs
)
makedepends=(
cmake
git
)
#cmake 4 patch
#https://github.com/google/crc32c/commit/2bbb3be42e20a0e6c0f7b39dc07dc863d9ffbc07
_tag='2bbb3be42e20a0e6c0f7b39dc07dc863d9ffbc07'
source=("${pkgname}::git+https://github.com/google/crc32c.git#tag=${_tag}")
sha256sums=('622e752bac7eb19110e53639b1c86ae9188a4882dca8796f81eb0bcb088262f1')
build() {
cd "${pkgname}"
cmake -B build -S . \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_SHARED_LIBS=yes \
-DCRC32C_BUILD_TESTS=OFF \
-DCRC32C_BUILD_BENCHMARKS=OFF \
-DCRC32C_USE_GLOG=OFF \
-DCRC32C_INSTALL=ON \
-Wno-dev
cmake --build build
}
package() {
cd "${pkgname}"
DESTDIR="$pkgdir" cmake --install build
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
# vim:set ts=2 sw=2 et:
|