PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Juan Simón <play4pro@protonmail.com>

pkgname=gosearch-git
pkgver=r44.71829c9
pkgrel=1
pkgdesc="A fast, real-time file searching program for linux"
url="https://github.com/ozeidan/gosearch"
arch=('x86_64')
license=('GPL3')
makedepends=(go-pie git)
depends=('linux>=5.1')
provides=("${pkgname%-git}")
conflicts=("${provides[@]}")
source=("${pkgname}::git+${url}")
sha256sums=('SKIP')

install="gosearch.install"

pkgver() {
	cd ${srcdir}/${pkgname}

	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare(){
  mkdir -p gopath/src/github.com/ozeidan
  ln -rTsf $pkgname gopath/src/github.com/ozeidan/$pkgname
  export GOPATH="$srcdir"/gopath
  export GO111MODULE=on
	cd gopath/src/github.com/ozeidan/$pkgname
	make deps
}

build() {
	export GOPATH="$srcdir"/gopath
	export GOFLAGS="-gcflags=all=-trimpath=${PWD} -asmflags=all=-trimpath=${PWD} -ldflags=-extldflags=-zrelro -ldflags=-extldflags=-znow"
	cd ${srcdir}/${pkgname}
	make all
}

package() {
	cd ${srcdir}/${pkgname}
	install -Dm755 gosearchServer "${pkgdir}"/usr/bin/gosearchServer
	install -Dm755 gosearch "${pkgdir}"/usr/bin/gosearch
	install -Dm644 init/gosearch.service "${pkgdir}"/usr/lib/systemd/system/gosearch.service   
}