blob: d88eba48a899545b76e6478d52ff5b7cd8937b0a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
|
# Maintainer: Hao Long <aur@esd.cc>
pkgname=gosec
pkgver=2.8.0
pkgrel=1
pkgdesc="Inspects source code for security problems by scanning the Go AST"
arch=("x86_64" "i686")
url="https://github.com/securego/gosec"
license=("Apache")
depends=("glibc")
makedepends=("go")
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/securego/gosec/archive/v${pkgver}.tar.gz")
sha256sums=('a607742f65bfea6cae52cbf1282b338ec9cff87161a4c6769e1ea355298e2e98')
build() {
cd ${pkgname}-${pkgver}/cmd/gosec
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build .
}
package() {
cd ${pkgname}-${pkgver}
install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
install -Dm755 cmd/gosec/gosec ${pkgdir}/usr/bin/gosec
}
|