PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: devome <evinedeng@hotmail.com>

pkgname=gotenberg
pkgver=8.21.0
pkgrel=1
pkgdesc='A developer-friendly API for converting numerous document formats into PDF files, and more!'
arch=(i686 pentium4 x86_64 arm armv7h armv6h aarch64 riscv64)
url="https://github.com/$pkgname/$pkgname"
license=(MIT)
backup=("etc/default/$pkgname")
depends=(chromium
         libreoffice-fresh
         pdfcpu
         pdftk
         perl-image-exiftool
         qpdf
         unoconv)
makedepends=(go)
_archive="$pkgname-$pkgver"
source=("$url/archive/refs/tags/v$pkgver/$_archive.tar.gz"
        "$pkgname.env"
        "$pkgname.service")
sha256sums=('9c69c7fadaea743e28e616358ebdb6e1f0d4f744c40434e33e8dec56cb0fd274'
            'd37f7a96701804c07bb08e123dd05e03a84368251fb0088c060c770d08e436ea'
            '1b3567e2fe374ce104150d198de3fe372724d3b8510aba64716e3dcb3b37c50a')

build() {
	cd "$_archive"
	export CGO_CPPFLAGS="$CPPFLAGS"
	export CGO_CFLAGS="$CFLAGS"
	export CGO_CXXFLAGS="$CXXFLAGS"
	local ldflags="
		-s -w \
		-X 'github.com/$pkgname/$pkgname/v8/cmd.Version=$pkgver' \
		-extldflags '$LDFLAGS'
	"
	go build -trimpath -o "$pkgname" -ldflags "$ldflags" "cmd/$pkgname/main.go"
}

package() {
	cd "$_archive"
	install -Dm644 "../$pkgname.env" "$pkgdir/etc/default/$pkgname"
	install -Dm644 -t "$pkgdir/usr/lib/systemd/system/" "../$pkgname.service"
	install -Dm755 -t "$pkgdir/usr/bin/" "$pkgname"
	install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
}