blob: 67d672c1fe1dee314c9ebe6fa772f0629a5abb6f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Philip Goto <philip.goto@gmail.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Andrew Simmons <andrew.simmons@gmail.com>
# Contributor: György Balló <ballogy@freestart.hu>
pkgname=gparted-git
pkgver=1.4.0.r85.g1d92c7aa
pkgrel=1
pkgdesc="A Partition Magic clone, frontend to GNU Parted"
arch=(i686 x86_64 armv7h aarch64)
url="https://gparted.org/"
license=('GPL')
provides=('gparted')
conflicts=('gparted')
depends=('parted' 'gtkmm3')
makedepends=('git' 'gnome-common' 'intltool' 'itstool' 'pkg-config' 'yelp-tools' 'polkit')
optdepends=('dosfstools: for FAT16 and FAT32 partitions'
'jfsutils: for jfs partitions'
'f2fs-tools: for Flash-Friendly File System'
'btrfs-progs: for btrfs partitions'
'exfat-utils: for exFAT partitions'
'ntfs-3g: for ntfs partitions'
'reiserfsprogs: for reiser partitions'
'udftools: for UDF file system support'
'xfsprogs: for xfs partitions'
'nilfs-utils: for nilfs2 support'
'polkit: to run gparted from application menu'
'gpart: for recovering corrupt partition tables'
'mtools: utilities to access MS-DOS disks')
source=("git+https://gitlab.gnome.org/GNOME/gparted.git")
sha256sums=('SKIP')
pkgver() {
cd gparted
git describe --long --tags | sed 's/^GPARTED_//;s/\([^-]*-g\)/r\1/;s/_/./g;s/-/./g'
}
build() {
cd gparted
gnome-autogen.sh --prefix=/usr \
--sbindir=/usr/bin \
--enable-online-resize \
--enable-libparted-dmraid \
--enable-xhost-root
make
}
package() {
cd gparted
make DESTDIR="${pkgdir}" install
# Install policy file
install -D -m0644 org.gnome.gparted.policy \
"${pkgdir}"/usr/share/polkit-1/actions/org.gnome.gparted.policy
}
|