blob: 0081805915868e01d213656f18a83f41ab5a88b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=gpg-tui-bin
pkgver=0.8.1
pkgrel=1
pkgdesc="A terminal user interface for GnuPG"
arch=('x86_64')
url="https://github.com/orhun/gpg-tui"
license=('MIT')
depends=('libxcb' 'libxkbcommon' 'gpgme')
optdepends=(
'xplr: for file selection support'
'xclip: for clipboard support on X11 (or xsel)'
'xsel: for clipboard support on X11 (or xclip)'
'wl-clipboard: for clipboard support on Wayland'
)
conflicts=("${pkgname%-bin}")
provides=("${pkgname%-bin}")
source_x86_64=("$url/releases/download/v$pkgver/${pkgname%-bin}-$pkgver-x86_64-unknown-linux-gnu.tar.gz"{,.sig})
sha512sums_x86_64=('73ff0a88142ed6e7c01fff27c0580788cb0c48b24c2ab2bbd5f37d96fe882e4f2037d900bfd9016053afc475c08a4d2305b8a652d6cbdfe1d502786d6d5bb79d'
'SKIP')
validpgpkeys=('14D49A4073C6899425D5315C1BC755D9FBD24068') # gpg-tui <gpg-tui@protonmail.com>
package() {
cd "${pkgname%-bin}-$pkgver"
install -Dm 755 "${pkgname%-bin}" -t "${pkgdir}/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm 644 "man/${pkgname%-bin}.1" -t "$pkgdir/usr/share/man/man1"
install -Dm 644 "man/${pkgname%-bin}.toml.5" -t "$pkgdir/usr/share/man/man5"
install -Dm 644 "completions/${pkgname%-bin}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname%-bin}"
install -Dm 644 "completions/${pkgname%-bin}.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d"
install -Dm 644 "completions/_${pkgname%-bin}" -t "${pkgdir}/usr/share/zsh/site-functions"
}
|