blob: 38681230d2d667b53f00ecfe4a016b7e7dcba97a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgbase=gpgme-git
pkgname=('gpgme-git' 'python-gpgme-git' 'qgpgme-qt5-git' 'qgpgme-qt6-git')
pkgver=1.22.0.r26.gab25df83
pkgrel=1
pkgdesc="GnuPG Made Easy"
arch=('i686' 'x86_64')
url="https://www.gnupg.org/related_software/gpgme/"
license=('LGPL')
makedepends=('git' 'gnupg' 'python' 'python-build' 'python-installer' 'python-setuptools'
'python-wheel' 'qt5-base' 'qt6-base' 'swig')
source=("git+https://dev.gnupg.org/source/gpgme.git")
sha256sums=('SKIP')
pkgver() {
cd "gpgme"
git describe --long --tags | sed 's/^gpgme-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "gpgme"
local _common_options=(
--prefix="/usr"
--disable-fd-passing
--disable-gpgsm-test
)
./autogen.sh
mkdir -p _build-qt{5,6}
pushd "_build-qt5"
../configure \
"${_common_options[@]}" \
--enable-languages=cpp,qt5
make
popd
pushd "_build-qt6"
../configure \
"${_common_options[@]}" \
--enable-languages=cpp,qt6
make
popd
./configure \
"${_common_options[@]}" \
--enable-languages=python
make
pushd "lang/python"
top_builddir="../.." \
python \
-m build \
--wheel \
--no-isolation
popd
}
check() {
cd "gpgme"
#make -C "_build-qt5" check
}
package_gpgme-git() {
depends=('gcc-libs' 'gnupg' 'libgpg-error')
provides=("gpgme=$pkgver" 'libgpgme.so' 'libgpgmepp.so')
conflicts=('gpgme')
cd "gpgme"
make -C "_build-qt5" DESTDIR="$pkgdir" install
# split packages
rm -r "$pkgdir/usr/lib"/{cmake/QGpgme,libqgpgme*}
}
package_python-gpgme-git() {
pkgdesc="Python bindings for GPGme"
depends=('python' 'gpgme-git')
provides=("python-gpgme=$pkgver")
conflicts=('python-gpgme')
cd "gpgme/lang/python"
make DESTDIR="$pkgdir" install
python \
-m installer \
--destdir="$pkgdir" \
dist/*.whl
}
package_qgpgme-qt5-git() {
pkgdesc="Qt5 bindings for GPGme"
depends=('gcc-libs' 'gpgme-git' 'qt5-base')
provides=("qgpgme-qt5=$pkgver")
conflicts=('qgpgme-qt5')
cd "gpgme"
make -C "_build-qt5/lang/qt" DESTDIR="$pkgdir" install
rm -r "$pkgdir/usr/include"
}
package_qgpgme-qt6-git() {
pkgdesc="Qt6 bindings for GPGme"
depends=('gcc-libs' 'gpgme-git' 'qt6-base')
provides=("qgpgme-qt6=$pkgver" 'qgpgme')
conflicts=('qgpgme-qt6')
replaces=('qgpgme')
cd "gpgme"
make -C "_build-qt6/lang/qt" DESTDIR="$pkgdir" install
rm -r "$pkgdir/usr/include"
}
|