summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 4341510bce5176aa47ddff7e672b8f6d3724ad9b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=gpm-git
pkgver=1.20.7.r38.ge82d1a6
pkgrel=1
pkgdesc="General purpose mouse daemon"
arch=('i686' 'x86_64')
url="https://www.nico.schottelius.org/software/gpm/"
license=('GPL')
depends=('glibc')
makedepends=('git')
provides=('gpm' 'libgpm.so')
conflicts=('gpm')
options=('staticlibs')
source=("git+https://github.com/telmich/gpm.git"
        "https://raw.githubusercontent.com/archlinux/svntogit-packages/packages/gpm/trunk/gpm.service"
        "https://raw.githubusercontent.com/archlinux/svntogit-packages/packages/gpm/trunk/gpm.sh")
sha256sums=('SKIP'
            'SKIP'
            'SKIP')


pkgver() {
  cd "gpm"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "gpm"

  ./autogen.sh
  ./configure \
    --prefix="/usr" \
    --sbindir="/usr/bin" \
    --sysconfdir="/etc"
  make
}

check() {
  cd "gpm"

  make check
}

package() {
  cd "gpm"

  make DESTDIR="$pkgdir" install

  install -Dm755 "$srcdir/gpm.sh" -t "$pkgdir/etc/profile.d"
  install -Dm644 "$srcdir/gpm.service" -t "$pkgdir/usr/lib/systemd/system"
}