blob: 5bc9795a1925525c31ee790fc8fff0d37c2a9d89 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: xiretza <xiretza+aur@gmail.com>
# Maintainer: Rod Kay <charlie5 on #ada at freenode.net>
# Contributor: Pierre-Marie de Rodat <pmderodat on #ada at freenode.net>
# Contributor: Earnestly <zibeon AT googlemail.com>
pkgname=gprbuild-bootstrap
epoch=1
pkgver=21.0.0
pkgrel=1
pkgdesc="Static GPRbuild to bootstrap XML/Ada and GPRbuild itself"
arch=('i686' 'x86_64')
url='https://github.com/AdaCore/gprbuild/'
license=('GPL3')
depends=('gcc-ada')
source=(
"gprbuild-$pkgver.tar.gz::https://github.com/AdaCore/gprbuild/archive/v$pkgver.tar.gz"
"xmlada-$pkgver.tar.gz::https://github.com/AdaCore/xmlada/archive/v$pkgver.tar.gz"
"gprconfig_kb-$pkgver.tar.gz::https://github.com/AdaCore/gprconfig_kb/archive/v$pkgver.tar.gz"
)
sha256sums=('54b7d1a3298160109aaee4d8c263c1ab3ab4abae75d354f3e90a4c51639167a2'
'923024931f0c57451aa52cb9a3333874646102cb75957f27e3689670f90edc1e'
'2aec26afad5bb1a4685d9c041c9c797ff5beda211a5e81f2a97452d2ceabc557')
prepare() {
cd "$srcdir/gprbuild-$pkgver"
# GPRbuild hard-codes references to /usr/libexec, but ArchLinux packages
# must use /usr/lib instead.
sed -i 's/libexec/lib/g' doinstall gprbuild.gpr \
"$srcdir/gprconfig_kb-$pkgver/db/compilers.xml" \
"$srcdir/gprconfig_kb-$pkgver/db/linker.xml" \
"$srcdir/gprconfig_kb-$pkgver/db/gnat.xml"
}
build() {
cd "$srcdir/gprbuild-$pkgver"
export GNATMAKEFLAGS="$MAKEFLAGS"
./bootstrap.sh \
--with-xmlada="$srcdir/xmlada-$pkgver" \
--with-kb="$srcdir/gprconfig_kb-$pkgver" \
--build
}
package() {
cd "$srcdir/gprbuild-$pkgver"
env DESTDIR="$pkgdir" ./bootstrap.sh \
--with-kb="$srcdir/gprconfig_kb-$pkgver" \
--prefix=/usr \
--libexecdir=/lib \
--install
}
# vim: set et ts=4:
|