blob: ab228d290ef2ace7209a8eb3a5653e9cb157440e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Jefferson Gonzalez <jgmdev@gmail.com>
pkgname=gpt4all-chat-git
_gitname=gpt4all
pkgver=r1150.c8d761a
pkgrel=1
pkgdesc="Cross platform Qt based GUI for GPT4All versions"
arch=('x86_64')
url="https://github.com/nomic-ai/gpt4all"
license=('MIT')
makedepends=('cmake' 'git')
depends=(
'qt6-base' 'qt6-httpserver' 'qt6-quickcontrols2' 'qt6-svg'
'qt6-webengine' 'qt6-shadertools' 'qt6-5compat' 'qt6-wayland'
)
conflicts=('gpt4all-chat')
provides=('gpt4all-chat')
source=(
"${_gitname}::git+https://github.com/nomic-ai/gpt4all.git"
"gpt4all-chat.desktop"
)
sha256sums=(
'SKIP'
'16cd7d32166c493b1028c3e5c6a8437d3d81315c92076f5a94240e509a93a271'
)
pkgver() {
cd "${srcdir}/${_gitname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${_gitname}"
git submodule update --init --recursive
mkdir -p gpt4all-chat/build
sed -i '/CMAKE_INSTALL_PREFIX/d' gpt4all-chat/CMakeLists.txt
}
build() {
cd "${srcdir}/${_gitname}/gpt4all-chat/build"
cmake -DCMAKE_INSTALL_PREFIX=/opt/gpt4all-chat -DCMAKE_BUILD_TYPE=Release ..
make
}
package() {
cd "${srcdir}/${_gitname}/gpt4all-chat/build"
DESTDIR="${pkgdir}" make install
mv "${pkgdir}/opt/gpt4all-chat/bin/chat" "${pkgdir}/opt/gpt4all-chat/bin/gpt4all-chat"
mkdir -p "${pkgdir}/usr/share/applications"
mkdir -p "${pkgdir}/usr/share/icons/hicolor/scalable/apps"
cp "${srcdir}/gpt4all-chat.desktop" "${pkgdir}/usr/share/applications/"
cp ../icons/logo.svg "${pkgdir}/usr/share/icons/hicolor/scalable/apps/gpt4all-chat.svg"
}
|