blob: d1eedd4e90d2be5a19c6d4b681f78bbc99b32f2e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Ingo Meyer <i.meyer@fz-juelich.de>
pkgname="gr-framework-git"
pkgver="0.72.10.r57.g3e08f096"
pkgrel="1"
pkgdesc="A universal framework for cross-platform visualization applications."
arch=("i686" "x86_64" "armv6h" "armv7h" "aarch64")
url="https://gr-framework.org"
license=("MIT")
depends=("bzip2" "cairo" "fontconfig" "freetype2" "ghostscript" "glfw-x11" \
"libjpeg-turbo" "libpng" "libtiff" "libx11" "libxft" "libxt" "pixman" \
"qhull" "qt5-base" "zlib")
makedepends=("git" "cmake")
optdepends=("ffmpeg: video support" "libxml2: XML parsing and validation support")
provides=("${pkgname%-*}=${pkgver}")
conflicts=("${pkgname%-*}")
source=("${pkgname%-*}::git+https://github.com/sciapp/gr.git#branch=develop")
sha256sums=("SKIP")
pkgver() {
cd "${srcdir}/${pkgname%-*}" || return
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${srcdir}/${pkgname%-*}" || return
cmake -DCMAKE_INSTALL_PREFIX=/usr/gr \
-DCMAKE_BUILD_TYPE=Release \
-DGR_USE_BUNDLED_LIBRARIES=OFF \
-S . \
-B build && \
cmake --build build
}
package() {
cd "${srcdir}/${pkgname%-*}" || return
DESTDIR="${pkgdir}" cmake --install build && \
mkdir -p "${pkgdir}/usr/bin/" && \
ln -s /usr/gr/bin/grplot "${pkgdir}/usr/bin/"
}
|