blob: 3ca55c5073a251050527d9630d790ec7d78d3376 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Lucas Werkmeister <mail@lucaswerkmeister.de>
java_=11
pkgname="graalwasm-jdk${java_}-bin"
pkgver=22.3.1
pkgrel=1
pkgdesc="GraalVM-based, high-performance WebAssembly platform, Java ${java_} version"
arch=('x86_64'
'aarch64')
url='https://github.com/oracle/graal'
license=('custom')
depends=("jdk${java_}-graalvm-bin")
source_x86_64=("https://github.com/graalvm/graalvm-ce-builds/releases/download/vm-${pkgver}/wasm-installable-svm-java${java_}-linux-amd64-${pkgver}.jar")
source_aarch64=("https://github.com/graalvm/graalvm-ce-builds/releases/download/vm-${pkgver}/wasm-installable-svm-java${java_}-linux-aarch64-${pkgver}.jar")
sha256sums_x86_64=('8b7a6ab2d91b9f325ca27144b5fdfab55a5cf35ed0e014c1fabfcab8219667a7')
sha256sums_aarch64=('818a7b5af4ecb7f3d3e97cf9f9ee8816560d00158b9de32f9cd7eb1b4895c7b4')
package() {
local file eq permissions mode name target
mkdir -p "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/"
cp -a -t "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/" languages/ lib/ LICENSE_WASM.txt
printf '\n' >> META-INF/permissions
while read -r file eq permissions; do
if [[ $eq != '=' ]]; then
printf >&2 'second word should be "=": %s %s %s\n' "$file" "$eq" "$permissions"
return 1
fi
case $permissions in
'rw-------') mode=600;;
'rw-r--r--') mode=644;;
'rw-rw-r--') mode=664;;
'rwxr-xr-x') mode=755;;
'rwxrwxr-x') mode=775;;
'rwxrwxrwx') continue;; # symbolic link
*)
printf >&2 'unknown permissions: %s\n' "$permissions"
return 1
;;
esac
chmod "$mode" -- "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/$file"
done < META-INF/permissions
printf '\n' >> META-INF/symlinks
while read -r name eq target; do
if [[ $eq != '=' ]]; then
printf >&2 'second word should be "=": %s %s %s\n' "$name" "$eq" "$target"
return 1
fi
mkdir -p -- "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/$(dirname -- "$name")"
ln -s -- "$target" "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/$name"
done < META-INF/symlinks
# already in jdk${java_}-graalvm-bin package
unlink "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/lib/installer/components/org.graalvm.component"
install -DTm644 LICENSE_WASM.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|