blob: 83f8f50d1f55d493396cf38b3b094cbce9b9fc08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
pkgname=grabclip-git
pkgver=r1.8b0201b
pkgrel=1
pkgdesc="Native GTK media downloader for Linux"
arch=('x86_64' 'aarch64')
url="https://gitlab.com/garethmcc/grabclip"
license=('MIT')
depends=('gtk4' 'libadwaita' 'yt-dlp' 'ffmpeg')
makedepends=('cargo' 'git')
provides=('grabclip')
conflicts=('grabclip')
source=("git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/grabclip"
printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/grabclip"
cargo build --release --locked
}
package() {
cd "$srcdir/grabclip"
install -Dm755 "target/release/grabclip" "$pkgdir/usr/bin/grabclip"
install -Dm644 "packaging/linux/grabclip.desktop" \
"$pkgdir/usr/share/applications/grabclip.desktop"
install -Dm644 "assets/icons/grabclip.svg" \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/grabclip.svg"
install -Dm644 LICENSE \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|