PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Maintainer: Michael Langer <laminarlade at t-online DOT de>
pkgname=gradia
pkgver=1.12.1
pkgrel=1
pkghash=9b70a5c3ced86a469d8750a452a68ebd7e983051
pkgdesc="Make your screenshots ready for the world."
arch=('x86_64')
url="https://github.com/AlexanderVanhee/Gradia"
license=('GPL-3.0-only')
depends=(
    'dconf'
    'graphene'
    'libsoup3'
    'hicolor-icon-theme'
    'pango'
    'glibc'
    'gdk-pixbuf2'
    'glib2'
    'gtk4>=4.12.0'
    'libadwaita>=1.5.0'
    'libportal>=0.9.1'
    'gtksourceview5>=5.16.0'
    'python'
    'python-gobject>=3.48.0'
    'python-pillow'
    'python-cairo'
    'python-pytesseract'
)
makedepends=(
    'patch'
    'meson'
    'blueprint-compiler'
)
options=('!debug')
source=(
#    "$pkgname-$pkgver.tar.gz::${url}/archive/refs/tags/v$pkgver.tar.gz"
    "$pkgname-$pkgver.zip::${url}/archive/$pkghash.zip"
    "gradia_ocr.patch"
)
sha256sums=('e0cfe26530e05e6542e184446be35cc22d5785852bd6221baaf129177183d6b3'
            '770b874fed71ec84a6a190b6e931be9189f512b4433eaef8996dca32644472d7')

prepare() {
  mv Gradia-$pkghash $pkgname-$pkgver
#  mv Gradia-$pkgver $pkgname-$pkgver
  patch -d $pkgname-$pkgver -p1 < gradia_ocr.patch
}

build() {
  arch-meson $pkgname-$pkgver build -Docr_tesseract_cmd=/usr/bin/tesseract -Docr_original_tessdata_dir=/usr/share/tessdata
  meson compile -C build
}

check() {
  true

#  Check fail with double include error for StartupNotify, doesn't seems to hurt
#  suspend for now
#  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}